扫码关注官方微信

扫码下载APP
返回顶部
首页 > 资讯 > 前端开发 > node.js >asp实现简单的ajax留言板实例代码
  • 444

0
分享到

asp实现简单的ajax留言板实例代码

2024-04-02 19:04:59 444人浏览 八月长安
摘要

index.asp<%@ codepage=65001%><%option explicit%><% Response.Charset="



index.asp
<%@ codepage=65001%>
<%
option explicit
%>
<% Response.Charset="utf-8"%>
<% Session.CodePage=65001 %>
<!-- #include file="AccHelper.asp" -->
<!-- #include file="Common.asp"-->
<!-- #include file="DAL_Guest.asp" -->
<!-- #include file="MOD_Guest.asp" -->
<!-- #include file="BLL_Guest.asp" -->
<%
 Dim mybll
 Dim myList
 Set mybll = new BLL_Guest
 Select Case Request("tCMD")
  Case "SAVE"
   mybll.Insert()
  Case "DEL"
   mybll.Delete()
 End Select
 myList = mybll.FindByPage()
%>
<h3>客户留言</h3>
<p>
<fORM name="subForm" id="subForm">
 <textarea id="con" name="con" cols="56" rows="6" wrap="VIRTUAL"></textarea>
 <input type="button" name="submit" value="提交留言" onclick="$('guest/index.asp?tCMD=SAVE&content='+escape(this.form.con.value))" />
</form>
</p>
<%=myList%>

BLL_Guest.asp
<%
 '/// <summary>
 '/// 摘要说明。
 '/// </summary>
 Class BLL_Guest

  Private mycom,mymod,mydal

  Private LI,UL

  Private DEL

  '获取信息
  Public Sub GetGuest()

   mydal.GetGuest(Id)

  End Sub

  '新增信息
  Public Sub Insert()

   mymod.Content = Request("content")
   mymod.re = Request("Re")
   mymod.Addtime = Now()
   mymod.Ip = request.servervariables("Http_X_FORWARDED_FOR")
   If len(mymod.Ip)<=0 Then mymod.Ip = request.servervariables("REMOTE_ADDR")

   Call mydal.Insert(mymod)

  End Sub

  '更新信息
  Public Sub Update()

   Call mydal.Update(mymod)

  End Sub

  '删除信息
  Public Sub Delete()

   mydal.Delete(Request("Id"))

  End Sub

  '查找信息
  Public Function FindByPage()

   Dim PageSize,CurrentPage,WhereValue,OrderValue,RecordCount
   Dim objRS
   Dim tmp1,tmp2,tmp3,parms,i
   Dim tCMD
   tCMD = Request("tCMD")
   PageSize = "8"
   CurrentPage = Request("PageNo")
   If Len(CurrentPage)<=0 Then
    CurrentPage=1
   End If
   WhereValue = ""
   OrderValue = "Id"
   Set objRS = mydal.FindByPage(PageSize,CurrentPage-1,WhereValue,OrderValue)
   i = 1
   RecordCount = mydal.Count(WhereValue)
   Do While Not objRS.EOF
    If tCMD="DEL" Then
     DEL = "<a href=""?tCMD=DEL&Id="&objRS("Id")&""">删除</a>"
    Else
     DEL = ""
    End If
    parms=Array(i,objRS("content"),objRS("ip"),objRS("addtime"),DEL)
    tmp1 = tmp1 & mycom.Format(LI,parms)
    objRs.Movenext
    i = i + 1
   Loop
   tmp3 = mycom.Page(PageSize,CurrentPage,RecordCount,"guest/index.asp?tCMD=LIST")
   parms=Array(tmp1,tmp3)
   tmp2 = tmp2 & mycom.Format(UL,parms)

   FindByPage = tmp2

  End Function

  Private Sub Class_Initialize()

   LI = "<li><span>{0}</span> <span>{1}</span><br /><span>作者:{2}</span> <span>{3}</span> <span>{4}</span></li>" & vbCrLf
   UL = "<UL>{0}<li>{1}</li></UL>"
   DEL = ""

   Set mycom = new Common
   set mymod = new MOD_Guest
   set mydal = new DAL_Guest

  End Sub

  Private Sub Class_Terminate()

   Set mycom = Nothing
   Set mymod = Nothing
   set mydal = Nothing

  End Sub

 End Class
%>

DAL_Guest.asp
<%
 '/// <summary>
 '/// 摘要说明。
 '/// </summary>
 Class DAL_Guest

  Private sql_01
  Private SQL_02
  Private SQL_03
  Private SQL_04
  Private SQL_05
  Private SQL_06
  Private SQL_07

  Private mycom,myacc,mymod

  '/// <summary>
  '/// 获得信息
  '/// </summary>
  '/// <param name="Id">判断字段</param>
  '/// <returns>信息体</returns>
  Public Function GetGuest(Id)

   Dim parms,SQL,objRS
   parms = Array(Id)
   SQL  = mycom.Format(SQL_01,parms)
   Set objRS = myacc.ExecuteReader(myacc.CONN_STRING,SQL)
   If  Not objRS.EOF then
    Call mymod.SetVar(objRs("Id"),objRs("Content"),objRs("Re"),objRs("Addtime"),objRs("Ip"))
    Set GetGuest = mymod
   Else
    GetGuest = Null
   End If

  End Function

  '/// <summary>
  '/// 插入信息
  '/// </summary>
  '/// <param name="">信息体</param>
  Public Sub Insert(vmod)

   Dim parms,SQL
   parms = Array(vmod.Content,vmod.Re,vmod.Addtime,vmod.Ip)
   SQL  = mycom.Format(SQL_02,parms)
   Call myacc.ExecuteReader(myacc.CONN_STRING,SQL)

  End Sub

  '/// <summary>
  '/// 更新信息
  '/// </summary>
  '/// <param name="">信息体</param>
  Public Sub Update(vmod)

   Dim parms,SQL
   parms = Array(vmod.Id,vmod.Content,vmod.Re,vmod.Addtime,vmod.Ip)
   SQL  = mycom.Format(SQL_03,parms)
   Call myacc.ExecuteReader(myacc.CONN_STRING,SQL)

  End Sub

  '/// <summary>
  '/// 删除信息
  '/// </summary>
  '/// <param name="">信息体</param>
  Public Sub Delete(Id)

   Dim parms,SQL
   parms = Array(Id)
   SQL  = mycom.Format(SQL_04,parms)
   Call myacc.ExecuteNonQuery(myacc.CONN_STRING,SQL)

  End Sub

  '/// <summary>
  '/// 统计信息
  '/// </summary>
  '/// <param name="">信息体</param>
  Public Function Count(WhereValue)

   Dim parms,SQL,objRS
   parms = Array(WhereValue)
   SQL  = mycom.Format(SQL_07,parms)
   Set objRS = myacc.Recordset(myacc.CONN_STRING,SQL)
   Count = objRS.RecordCount

  End Function

  '/// <summary>
  '/// 根据条件列出所有信息(带有分页)
  '/// </summary>
  '/// <param name="PageSize">每页记录数</param>
  '/// <param name="CurrentPage">页码</param>
  '/// <param name="WhereValue">判断值</param>
  '/// <param name="OrderValue">排序</param>
  '/// <returns>返回objRS</returns>
  Public Function FindByPage(PageSize,CurrentPage,WhereValue,OrderValue)

   Dim parms,SQL,objRS
   Dim s1
   If CurrentPage="0" Then   
    s1 =  PageSize & "|" + OrderValue & "|" & WhereValue
    parms = Split(s1,"|")
    SQL = mycom.Format(SQL_05,parms)
   Else
    s1 = PageSize & "|" & OrderValue & "|" + WhereValue & "|" & CurrentPage*PageSize
    parms = Split(s1,"|")
    SQL = mycom.Format(SQL_06,parms)
   End If

   Set objRS = myacc.ExecuteReader(myacc.CONN_STRING,SQL)
   Set FindByPage = objRS

  End Function


  Private Sub Class_Initialize()

   SQL_01 = "Select * From [Guest] Where Id = {0}"
   SQL_02 = "Insert into [Guest] ([Content],[Re],[Addtime],[Ip]) values('{0}','{1}','{2}','{3}')"
   SQL_03 = "Update [Guest] Set [Content]='{1}',[Re]='{2}',[Addtime]='{3}',[Ip]='{4}' Where Id = {0}"
   SQL_04 = "Delete From [Guest] Where Id In ({0})"
   SQL_05 = "Select Top {0} * From [Guest] Where Content Like '%{2}%' Order By {1} Desc,Id Desc"
   SQL_06 = "Select Top {0} * From [Guest] Where Content Like '%{2}%' And Id Not IN(Select Top {3} Id From [Guest] Where Content Like '%{2}%' Order By {1} Desc,Id Desc) Order By {1} Desc,Id Desc"
   SQL_07 = "Select * From [Guest] Where Content Like '%{0}%' "

   Set mycom = new Common
   Set myacc = new AccHelper
   Set mymod = new MOD_Guest

  End Sub

  Private Sub Class_Terminate()

   Set mycom = Nothing
   Set myacc = Nothing
   Set mymod = Nothing

  End Sub

 End Class
%>

MOD_Guest.asp
<%
 '/// <summary>
 '/// 摘要说明。
 '/// </summary>
 Class MOD_Guest

  Public Id
  Public Content
  Public Re
  Public Addtime
  Public Ip

  Public Sub SetVar(vId,vContent,vRe,vAddtime,vIp)
   Id=vId
   Content=vContent
   Re=vContent
   Addtime=vAddtime
   Ip=vIp
  End Sub

 End Class
%>

Common.asp
<%
 '/// <summary>
 '/// 摘要说明
 '/// </summary>
 Class Common

  '/// <summary>
  '/// 获得信息
  '/// </summary>
  '/// <param name="Id">需要内容</param>
  '/// <param name="Id">替换关键字</param>
  '/// <returns>格式化后内容</returns>
  Public Function Format(str,arr)

   Dim r,i
   r = str   
   For i = 0 To UBound(arr)
    r = Replace(r,"{"&i&"}",arr(i))
   Next
   Format = r

  End Function

  Public Function Page(PageSize,CurrentPage,RecordCount,PageUrl)

   const C_RECORDCOUNT = "合计<STRONG><FONT color=""red"">{0}</FONT></STRONG>篇&nbsp;|"
   const C_FIRSTPAGE1 = "&nbsp;<a href=""#"" onclick=""$('{0}&amp;PageNo={1}')"">首页</a>"
   const C_FIRSTPAGE2 = "&nbsp;首页"
   const C_PREVPAGE1 = "&nbsp;<a href=""#"" onclick=""$('{0}&amp;PageNo={1}')"">上一页</a>"
   const C_PREVPAGE2 = "&nbsp;上一页"
   const C_NEXTPAGE1 = "&nbsp;<a href=""#"" onclick=""$('{0}&amp;PageNo={1}')"">下一页</a>"
   const C_NEXTPAGE2 = "&nbsp;下一页"
   const C_LASTPAGE1 = "&nbsp;<a href=""#"" onclick=""$('{0}&amp;PageNo={1}')"">尾页</a>"
   const C_LASTPAGE2 = "&nbsp;尾页"
   const C_CURRENTPAGE = "&nbsp;页次：<STRONG><FONT color=""red"">{0}</FONT>/{1}</STRONG>页"
   const C_PAGESIZE = "&nbsp;<STRONG>{0}</STRONG>篇/页&nbsp;&nbsp;"
   const C_GoTOPAGE = "&nbsp;跳转：<input type=""text"" name=""goto"" value=""{1}"" onchange=""$('{0}&amp;PageNo='+this.value)"" width:20px;border:1px""/>&nbsp;&nbsp;"

   Dim PageCount,pages
   Dim lRecordCount,lFirstpage,lPrevpage,lNextpage,lLastpage,lCurrentpage,lPagesize,lGotopage
   Dim p,parms

   If RecordCount Mod PageSize <> 0 Then
    pages = 1
   else
    pages = 0
   End If
   PageCount=CInt(RecordCount/PageSize + pages)

   parms=Array(RecordCount)
   lRecordCount = Format(C_RECORDCOUNT,parms)

   if CInt(CurrentPage)>1 Then
    parms=Array(Pageurl,1)
    lFirstpage = Format(C_FIRSTPAGE1,parms)
    parms=Array(Pageurl,CInt(CurrentPage)-1)
    lPrevpage = Format(C_PREVPAGE1,parms)
   Else
    lFirstpage=C_FIRSTPAGE2
    lPrevpage=C_PREVPAGE2
   End If

   if CInt(CurrentPage)<PageCount Then
    parms=Array(Pageurl,CInt(CurrentPage)+1)
    lNextpage = Format(C_NEXTPAGE1,parms)
    parms=Array(Pageurl,CInt(CurrentPage)+1)
    lLastpage = Format(C_LASTPAGE1,parms)
   Else   
    lNextpage=C_NEXTPAGE2
    lLastpage=C_LASTPAGE2
   End If

   parms=Array(CurrentPage,PageCount)
   lCurrentpage = Format(C_CURRENTPAGE,parms)
   parms=Array(PageSize)
   lPagesize = Format(C_PAGESIZE,parms)
   parms=Array(Pageurl,CurrentPage)
   lGotopage = Format(C_GOTOPAGE,parms)

   p=lRecordCount&lFirstpage&lPrevpage&lNextpage&lLastpage&lCurrentpage&lPagesize&lGotopage
   Page = p

  End Function

 End Class
%>

AccHelper.asp
<%
 '/// <summary>
 '/// AccHelper 的摘要说明。
 '/// </summary>
 Class AccHelper

  Public CONN_STRING

  '/// <summary>
  '/// 执行ExecuteNonQuery
  '/// </summary>
  '/// <param name="connString">连接字符</param>
  '/// <param name="cmdText">sql命令</param>
  Public Function ExecuteNonQuery(connString,cmdText)

   Dim objConn
   Set objConn = Server.CreateObject("ADODB.Connection")
   objConn.Open connString
   objConn.Execute(cmdText)

  End Function

  '/// <summary>
  '/// 执行ExecuteReader
  '/// </summary>
  '/// <param name="connString">连接字符</param>
  '/// <param name="cmdText">sql命令</param>
  '/// <returns>RS</returns>
  Public Function ExecuteReader(connString,cmdText)

   Dim objConn,objRS
   Set objConn = Server.CreateObject("ADODB.Connection")
   objConn.Open connString
   Set objRS = objConn.Execute(cmdText)
   Set ExecuteReader = objRS

  End Function

  '/// <summary>
  '/// 执行Recordset
  '/// </summary>
  '/// <param name="connString">连接字符</param>
  '/// <param name="cmdText">sql命令</param>
  '/// <returns>RS</returns>
  Public Function Recordset(connString,cmdText)

   Dim objConn,objRS
   Set objConn = Server.CreateObject("ADODB.Connection")
   objConn.Open connString
   Set objRS = Server.CreateObject("ADODB.RecordSet")
   objRS.Open cmdText,objConn,1,3
   Set Recordset = objRS

  End Function

  Private Sub Class_Initialize()
   CONN_STRING = "provider = microsoft.jet.oledb.4.0;data source=" & Server.Mappath("db.mdb")
  End Sub

 End Class
%>
ajax.js

代码如下:


var http_request = false;

function makeRequest(obj,url) {

    http_request = false;

    if (window.XMLHttpRequest) { // Mozilla, Safari,...
        http_request = new XMLHttpRequest();
        if (http_request.overrideMimeType) {
            http_request.overrideMimeType('text/xml');
        }
    } else if (window.ActiveXObject) { // IE
        try {
            http_request = new ActiveXObject("Msxml2.XMLHTTP");
        } catch (e) {
            try {
            http_request = new ActiveXObject("Microsoft.XMLHTTP");
            } catch (e) {}
        }
    }

    if (!http_request) {
        alert('Giving up :( Cannot create an XMLHTTP instance');
        return false;
    }

    http_request.onreadystatechange = function()
    {
        if (http_request.readyState == 4) {
            if (http_request.status == 200) {
                updateObj(obj,http_request.responseText);
            }
            else
            {
                updateObj(obj,"");
            }
        }
    }
    http_request.open('GET', url, true);
    http_request.send(null);
}

function updateObj(obj,data){
    obj.innerhtml = data;
}
function $(url){
    var obj = document.getElementById("content");
    obj.style.display='block';
    document.getElementById("container").style.margin="10px auto 0px";
    obj.innerHTML = "Loading…";
    makeRequest(obj,url);
}


html调用方法：

代码如下:


<a href="#" onclick="$('news.html')">新闻</a><a href="#" onclick="$('product.html')">产品</a><a href="#" onclick="$('case.html')">案例</a><a href="#" onclick="$('contact.html')">联系</a><a href="http://zj55com.cnblogs.com/" target="_blank">博客</a>

--结束END--

本文标题: asp实现简单的ajax留言板实例代码

本文链接: https://lsjlt.com/news/80018.html(转载时请注明来源链接)

有问题或投稿请发送至: 邮箱/279061341@qq.com    QQ/279061341

猜你喜欢
  • asp实现简单的ajax留言板实例代码
    index.asp<%@ codepage=65001%><%option explicit%><% Response.Charset="...
    99+
    2024-04-02
  • asp怎么实现简单的ajax留言板
    这篇文章主要介绍“asp怎么实现简单的ajax留言板”，在日常操作中，相信很多人在asp怎么实现简单的ajax留言板问题上存在疑惑，小编查阅了各式资料，整理出简单好用的操作方法，希望对大家解答”asp怎么实...
    99+
    2024-04-02
  • JavaScriptDOM实现简单留言板
    本文实例为大家分享了JavaScript DOM实现简单留言板的具体代码，供大家参考，具体内容如下 效果图： 先准备html代码： <body>     <tex...
    99+
    2024-04-02
  • JS实现简单留言板功能
    本文实例为大家分享了JS实现简单留言板的具体代码，供大家参考，具体内容如下 言归正传，之前的案例相信大家都已经完全弄清楚了，还记得我们之前统计字数的那个案例吗？忘记的可以再去翻阅一下...
    99+
    2024-04-02
  • 如何实现ajax留言板
    小编给大家分享一下如何实现ajax留言板，相信大部分人都还不怎么了解，因此分享这篇文章给大家参考一下，希望大家阅读完这篇文章后大有收获，下面让我们一起去了解一下吧！代码如下:// JavaScri...
    99+
    2024-04-02
  • android实现简单的画画板实例代码
    直接看代码，注释都写清楚了 代码如下:public class MainActivity extends Activity { private ImageView ...
    99+
    2022-06-06
    画板 Android
  • HTML+PHP+MYSQL实现一个简单的留言板
    提示：这里可以添加系列文章的所有文章的目录，目录需要自己手动添加 大家好，下面将为大家展示 基于HTML PHP MYSQL的留言板的设计与实现过程，适合初学者点击观看，以下我将会以笔者自称！ 废...
    99+
    2023-09-05
    mysql php html javascript css
  • asp留言板功能怎么实现
    ASP留言板功能可以通过以下步骤实现：1. 创建数据库：使用SQL Server或MySQL等数据库软件创建一个数据库，用于存储留言...
    99+
    2023-06-14
    asp留言板
  • php怎么实现简易留言板
    本文操作环境：Windows7系统，PHP7.4版，Dell G3电脑。php怎么实现简易留言板？PHP+MySql实现一个简单的留言板：//嗯，跟着书学的，代码不是自己写的，但是都能理解，有时间自己去写个好看一点的吼吼吼～（不熟练花了一天...
    99+
    2014-08-31
    php 留言板
  • php如何实现简易留言板
    小编给大家分享一下php如何实现简易留言板，相信大部分人都还不怎么了解，因此分享这篇文章给大家参考一下，希望大家阅读完这篇文章后大有收获，下面让我们一起去了解一下吧！php实现简易留言板的方法：1、在数据库中创建两张表；2、编写send页面...
    99+
    2023-06-22
  • 如何实现AJAX简单测试代码
    本篇内容主要讲解“如何实现AJAX简单测试代码”，感兴趣的朋友不妨来看看。本文介绍的方法操作简单快捷，实用性强。下面就让小编来带大家学习“如何实现AJAX简单测试代码”吧!具体如下：客户端：代码如下：（AJ...
    99+
    2024-04-02
  • Android ContentProvider的实现及简单实例代码
    一、概念及说明 ContentProvider定义： 内容提供者是一个Android应用的基础模块，提供内容给这个应用，它们封装数据和提供它给应用通过这个ContentRe...
    99+
    2022-06-06
    Android
  • 怎么用AJAX实现简单的聊天室代码
    本篇内容主要讲解“怎么用AJAX实现简单的聊天室代码”，感兴趣的朋友不妨来看看。本文介绍的方法操作简单快捷，实用性强。下面就让小编来带大家学习“怎么用AJAX实现简单的聊天室代码”吧! ...
    99+
    2024-04-02
  • node.js+express留言板功能实现示例
    目录留言板所需类库开源项目项目结构留言板 基于nodejs+express+art-template的留言板功能。包含列表界面、添加界面和发送留言功能。 所需类库 直接copy以下p...
    99+
    2024-04-02
  • C语言实现堆的简单操作的示例代码
    目录一、堆的概念二、堆的实现三、堆的代码实现一、堆的概念 （1）定义 如果有一个关键码的集合K = {k0，k1， k2，…，kn-1}，把它的所有元素按完全二叉树的顺...
    99+
    2022-11-13
    C语言实现堆 C语言 堆操作 C语言 堆
  • C#实现简易画图板的示例代码
    编程环境 VS2019、C# 画板功能演示 实现简单画图 打开功能 可打开jpg格式的文件 保存功能 可将绘画的内容保存为jpg文件 颜色选择功能 用户可自由选择所需的颜色...
    99+
    2024-04-02
  • Java WebService 简单实例(附实例代码)
    下面是一个简单的Java WebService实例，使用了JAX-WS标准：1. 编写WebService接口：```javaimp...
    99+
    2023-08-17
    Java
  • Django实现简单登录的示例代码
    目录创建django项目使用模型的url.py加载静态文件页面跳转创建数据库模型提交表单提交ajax提交创建django项目 创建项目的命令行语句： django-admin st...
    99+
    2024-04-02
  • Webview实现android简单的浏览器实例代码
    WebView是Android中一个非常实用的组件，它和Safai、Chrome一样都是基于Webkit网页渲染引擎，可以通过加载HTML数据的方式便捷地展现软件的界面，下面通...
    99+
    2022-06-06
    浏览器 webview Android
  • springboot简单实现单点登录的示例代码
    什么是单点登录就不用再说了，今天通过自定义sessionId来实现它，想了解的可以参考https://www.xuxueli.com/xxl-sso/ 讲一下大概的实现思路吧：这里有...
    99+
    2024-04-02
软考高级职称资格查询
热门wiki
近期文章
推荐阅读
热门问答
热门标签
编程网，编程工程师的家园，是目前国内优秀的开源技术社区之一，形成了由开源软件库、代码分享、资讯、协作翻译、讨论区和博客等几大频道内容，为IT开发者提供了一个发现、使用、并交流开源技术的平台。

  • 官方手机版

  • 微信公众号

  • 商务合作